Les tireurs fous.

Graphe de Markov :

Graph[{Style[1,Blue],Style[2,Red],Style[3,Red],Style[4,Red],Style[5,Orange],Style[6,Orange],Style[7,Orange],Style[8,Orange],Style[9,Green],Style[10,Green],Style[11,Green]},{1\[DirectedEdge]2,1\[DirectedEdge]3,1\[DirectedEdge]4,2\[DirectedEdge]3,2\[DirectedEdge]4,2\[DirectedEdge]5,3\[DirectedEdge]2,3\[DirectedEdge]4,4\[DirectedEdge]2,4\[DirectedEdge]3,4\[DirectedEdge]6,5\[DirectedEdge]7,5\[DirectedEdge]10,6\[DirectedEdge]8,6\[DirectedEdge]10,7\[DirectedEdge]5,7\[DirectedEdge]9,8\[DirectedEdge]6,8\[DirectedEdge]11},VertexCoordinates->{{0,0},{3,-6},{0,-3},{-3,-6}, {6,-6},{-6,-6}, {9,-8},{-9,-8},{9,-11},{0,-10},{-9,-11}},VertexSize->Large,EdgeStyle->Thick,VertexLabels->{1->Style[1,Medium,Bold],2->Style["2:A→B",Medium,Bold],3->Style["3:C↑",Medium,Bold],4->Placed[Style["4:B→A",Medium,Bold],{Before,Above}],5->Placed[Style["5:C→A",Medium,Bold],{After,Above}],6->Placed[Style["6:C→B",Medium,Bold],{Above,Before}],7->Style["7:A→C",Medium,Bold],8->Placed[Style["8:B→C",Medium,Bold],{Before,Above}],9->Placed[Style["9 : A!",Medium,Bold],Below],10->Placed[Style["10 : C!",Medium,Bold],Below],11->Placed[Style["11 : B!",Medium,Bold],Below]},EdgeLabels->{1\[DirectedEdge]2->Style["1/3",Medium,Bold],1\[DirectedEdge]3->Style["1/3",Medium,Bold],1\[DirectedEdge]4->Style["1/3",Medium,Bold],2\[DirectedEdge]3->Style["(1-a)/2",Medium,Bold],2\[DirectedEdge]4->Style["(1-a)/2",Medium,Bold],2\[DirectedEdge]5->Style["a",Medium,Bold],3\[DirectedEdge]2->Style["1/2",Medium,Bold],3\[DirectedEdge]4->Style["1/2",Medium,Bold],4\[DirectedEdge]2->Style["(1-b)/2",Medium,Bold],4\[DirectedEdge]3->Style["(1-b)/2",Medium,Bold],4\[DirectedEdge]6->Style["b",Medium,Bold],5\[DirectedEdge]7->Style["1-c",Medium,Bold],5\[DirectedEdge]10->Style["c",Medium,Bold],6\[DirectedEdge]8->Style["1-c",Medium,Bold],6\[DirectedEdge]10->Style["c",Medium,Bold],7\[DirectedEdge]5->Style["1-a",Medium,Bold],7\[DirectedEdge]9->Style["a",Medium,Bold],8\[DirectedEdge]6->Style["1-b",Medium,Bold],8\[DirectedEdge]11->Style["b",Medium,Bold]},EdgeShapeFunction->GraphElementData["FilledArrow"],ImagePadding->30,ImageSize->500]

Résolution du graphe de Markov par la méthode matricielle (Q=((Subscript[p, i,j])) est la matrice de transitions entre états internes et S tient compte des états de bord) :

Q=(({{0, 1/3, 1/3, 1/3, 0, 0, 0, 0}, {0, 0, (1-a)/2, (1-a)/2, a, 0, 0, 0}, {0, 1/2, 0, 1/2, 0, 0, 0, 0}, {0, (1-b)/2, (1-b)/2, 0, 0, b, 0, 0}, {0, 0, 0, 0, 0, 0, 1-c, 0}, {0, 0, 0, 0, 0, 0, 0, 1-c}, {0, 0, 0, 0, 1-a, 0, 0, 0}, {0, 0, 0, 0, 0, 1-b, 0, 0}}));

S=(({{0, 0, 0}, {0, 0, 0}, {0, 0, 0}, {0, 0, 0}, {0, c, 0}, {0, c, 0}, {a, 0, 0}, {0, 0, b}}));

Inverse[IdentityMatrix[8]-Q].S//Simplify//Factor//MatrixForm

Seule la première ligne compte si on ne s’intéresse qu’aux probabilités d’absorption :

pa[a_,b_,c_]:=(((a^2) (-3+b) (-1+c))/((-3 a-3 b+2 a b) (-a-c+a c)))

pb[a_,b_,c_]:=(((-3+a) (b^2) (-1+c))/((-3 a-3 b+2 a b) (-b-c+b c)))

pc[a_,b_,c_]:=-((c (6 a b-(a^2) b-a (b^2)+3 a c+3 b c-8 a b c+(a^2) b c+a (b^2) c))/((-3 a-3 b+2 a b) (-a-c+a c) (-b-c+b c)))

pa[a,b,c]+pb[a,b,c]+pc[a,b,c]//Simplify

Représentation graphique. Trois possibilités seulement : pa>pb>pc, pa>pc>pb, pc>pa>pb. Dans l’espace 3D, {a,b,c}, les séparatrices sont solutions positives de :

Solve[pa[a,b,c]==pc[a,b,c] ,c]

Solve[pb[a,b,c]==pc[a,b,c] ,c]

Les séparatrices déterminent les volumes correspondants à pa>pb>pc, pa>pc>pb, pc>pa>pb, en progressant selon une verticale, de bas en haut :

Plot3D[{(3 (a^2)-6 a b-6 (a^2) b+a (b^2)+2 (a^2) (b^2)+a (Sqrt[9 (a^2)+72 (b^2)-30 a (b^2)-24 (b^3)+8 a (b^3)+(b^4)]))/(2 (3 a+3 (a^2)+3 b-8 a b-3 (a^2) b+a (b^2)+(a^2) (b^2))),(-6 a b+(a^2) b+3 (b^2)-6 a (b^2)+2 (a^2) (b^2)+b (Sqrt[72 (a^2)-24 (a^3)+(a^4)-30 (a^2) b+8 (a^3) b+9 (b^2)]))/(2 (3 a+3 b-8 a b+(a^2) b+3 (b^2)-3 a (b^2)+(a^2) (b^2)))} && a>b,{a,0,1},{b,0,1},PlotRange->{{0,1},{0,1},{0,1}},RegionFunction->Function[{a,b,c},c<b<a],BoxRatios->Automatic,Axes->True,AxesLabel->{Style[a,Large,Bold],Style[b,Large,Bold],Style[c,Large,Bold]},PlotStyle->Thick,AxesStyle->Directive[Thickness[0.01]],LabelStyle->Directive[Medium,Bold],Background->LightPink]

Espace tétraédrique disponible, c<b<a :

RegionPlot3D[c<b<a,{a,0,1},{b,0,1},{c,0,1},PlotPoints->50,BoxRatios->Automatic,Axes->True,AxesLabel->{Style[a,Large,Bold],Style[b,Large,Bold],Style[c,Large,Bold]},PlotStyle->Thick,AxesStyle->Directive[Thickness[0.01]],LabelStyle->Directive[Medium,Bold],Background->LightPink]

Le volume correspondant au cas, pc>pa>pb est loin d’être négligeable !  Quelques exemples :

{pa[a,b,c],pb[a,b,c],pc[a,b,c]}/.{a->0.9,b->0.8,c->0.7}

{pa[a,b,c],pb[a,b,c],pc[a,b,c]}/.{a->0.9,b->0.8,c->0.4}

{pa[a,b,c],pb[a,b,c],pc[a,b,c]}/.{a->0.9,b->0.8,c->0.3}

{pa[a,b,c],pb[a,b,c],pc[a,b,c]}/.{a->0.9,b->0.8,c->0.2}